Menü

Mail Listen Archiv | Code Startseite | Anzeige aller Code Fragmente

4D Code Library

4D Support Center - 4D Code Beispiel zum Thema:

4D als HTTP-Client

Erfaßt von: Matthias Gruber (eMail: matthiasgru@web.de ) am 26.03.2004 ; -
Letzte Änderung: 26.03.2004

Kurzbeschriebung:

per HTTP Daten in ein 4D Blob laden. http://www.4d.com/docs/CMU/CMU79741.HTM http://archiv.de.4d.com/4DAction/OnlineMail/Forum=3_ID=544413 http://archiv.de.4d.com/4DAction/OnlineMail/Forum=3_ID=544460;

Beschreibung

Beschreibung ändern (nur für Autor - Kennwort geschützt) Keine Beschreibung für 4D als HTTP-Client

4D Code Beispiel

` httpRequest

` aufruf: $error:=HTTP_Request("<URL>";->vBLOB)
  `<URL> muss vollständig sein, also "<protokoll>://<host><path>"
  ` vBLOB muss initialisiert sein

`--------- compiler deklarationen -------

C_BOOLEAN($Stop_b;$EndStop_b)
C_LONGINT($0;$State_i;$i;$OffSet_i;$Error1_i;$Error2_i)
C_TEXT($1;$URL_t;$EndTag_t;$Buffer_t)
C_STRING(2;$CRLF)
C_TIME($Time_t)
C_POINTER($2;$Answer_px)

`C_LONGINT(HTTPPort_i;HTTPSessionID_i)  `ggf. in Compiler_Process deklarieren
  `C_TEXT(HTTPPath_t;HTTPHost_t)

`------------ interface -----------------

`$0 := tcp close status zurückgeben
$URL_t:=$1  `$1 enthält die URL
$Answer_px:=$2  `$2 zeigt auf das BLOB in dem die antwort gespeichert wird

$EndTag_t:="</html>"  `markiert das erwartete ende der antwort, 
  `(evtl auch noch als parameter übergeben)

` ----------- request  ---------------

httpURLParser ($URL_t)  ` HTTPHost_t, HTTPPath_t, HTTPPort_i aus der URL extrahieren

$CRLF:=Char(Carriage return )+Char(Line feed )
HTTPSessionID_i:=0

If (TCP_Open (HTTPHost_t;HTTPPort_i;HTTPSessionID_i)=0)  `tcp verbindung öffnen

$getMsg:=""  ` den http-request zusammenbauen.
`($getMsg den eigenen erfordernissen anpassen. prüfen laesst sich das gut mit curl)
$getMsg:=$getMsg+"GET "+HTTPPath_t+" HTTP/1.1"+$CRLF  `ggf. HTTP/1.0 ?!
$getMsg:=$getMsg+"Referer: bookmarks"+$CRLF
$getMsg:=$getMsg+"Connection: Keep-Alive"+$CRLF
$getmsg:=$getmsg+"User-Agent: Mozilla/7.0 (Longhorn Build 431)"+$CRLF
$getMsg:=$getMsg+"Host: "+HTTPHost_t+$CRLF  `nur für HTTP/1.1 zwingend
$getMsg:=$getMsg+"Accept: */*"+$CRLF
  `$getMsg:=$getMsg+"Accept-Encoding: gzip"+$CRLF
  `$getMsg:=$getMsg+"Accept-Language: en-US "+$CRLF
$getMsg:=$getMsg+"Accept-Language: de"+$CRLF
$getMsg:=$getMsg+"Accept-Charset: iso-8859-1,*,utf-8"+$CRLF+$CRLF

If (TCP_Send (HTTPSessionID_i;$getMsg)=0)  `den http-request senden
$State_i:=0
$Leer:=0
$i:=0
$OffSet_i:=0
$Time_t:=Current time(*)  `für timeout
$Stop_b:=False
$EndStop_b:=False

Repeat   `in der schleife die antwortpakete zu einem blob zusammenbauen
$i:=$i+1
$Error1_i:=TCP_Receive (HTTPSessionID_i;$Buffer_t)
If ($Buffer_t="")
$Leer:=$Leer+1  `zähler für leere antworten, max. 10 (sh. until)
End if 
$Error2_i:=TCP_State (HTTPSessionID_i;$State_i)  `tcp statuscheck
TEXT TO BLOB($Buffer_t;$Answer_px->;Text without length ;$OffSet_i)  `buffer ans antwort- blob anfügen
IDLE
If ((Current time(*)-$Time_t)>†00:02:00†)  `timeout 2 min
$Stop_b:=True
$EndStop_b:=False
Else 
If (Position($EndTag_t;$Buffer_t)>0)  `end-tag prüfen
$Stop_b:=False
$EndStop_b:=True
End if 
End if 
  `abbruchbedingungen:
Until (($State_i#8) | ($Error1_i#0) | ($Error2_i#0) | ($Stop_b) | ($EndStop_b) | ($Leer=10))

$0:=TCP_Close (HTTPSessionID_i)  `tcp verbindung schließen
End if 
End if 
  `----------- ende -------------

# ############### hilfs-prozeduren ##########################

` httpURLParser

`  see: http://www.4d.com/docs/CMU/CMU79741.HTM

`--------- compiler deklarationen -------

C_TEXT($1;$URL_t;$URI_t)
C_LONGINT($shift)

`C_LONGINT(HTTPPort_i)  `ggf. in Compiler_Process deklarieren
  `C_TEXT(HTTPPath_t;HTTPHost_t)

`------------ interface -----------------

$URL_t:=$1  `first parameter contains URL

` ------------ parser ------------------

`The first part of the code just checks if the user specified the protocol to be used in the URL

Case of 
: (Substring($URL_t;0;7)="http://")
$shift:=8
HTTPPort_i:=80

: (Substring($URL_t;0;7)="https://")
$shift:=9
HTTPPort_i:=443

Else 
$shift:=1
HTTPPort_i:=80  `use default port
End case

`The second part of the code sets host and path, if  ":<port>" is specified, it is used

If ((Position(":";Substring($URL_t;$shift))#0) & (Position(":";Substring($URL_t;$shift))<Position("/";Substring($URL_t;$shift))))
HTTPHost_t:=Substring($URL_t;$shift;Position(":";Substring($URL_t;$shift))-1)
If (Position("/";Substring($URL_t;$shift))#0)
HTTPPort_i:=Num(Substring($URL_t;Position(":";Substring($URL_t;$shift))+$shift;Position("/";Substring($URL_t;$shift))-Position(":";Substring($URL_t;$shift))-1))
Else 
HTTPPort_i:=Num(Substring($URL_t;Position(":";Substring($URL_t;$shift))+$shift;Length($shift)-Position(":";Substring($URL_t;$shift))-1))
End if

Else 
If (Position("/";Substring($URL_t;$shift))#0)
HTTPHost_t:=Substring($URL_t;$shift;Position("/";Substring($URL_t;$shift))-1)
Else 
HTTPHost_t:=Substring($URL_t;$shift)
End if 
End if

`The third part sets the document path

$URI_t:=Substring($URL_t;Length(HTTPHost_t)+$shift)  `encode the string passed as URL into a URL format.

If (Position("/";$URI_t)#0)
HTTPPath_t:=httpURLEncoder ($URI_t)
Else 
HTTPPath_t:="/"
End if 
`--------------- end ----------------

####################

` httpURLEncoder

`  see: http://www.4d.com/docs/CMU/CMU79741.HTM

`--------- compiler deklarationen -------

C_TEXT($0)
C_TEXT($1;$WSPI_MyString)
C_LONGINT($WSPI_parser;$WSPI_n)
C_STRING(1;$WSPI_MyChar)

`------------ interface -----------------

`$0 codierte URI zurückgenen
$WSPI_MyString:=$1

` ----------- encoder  ---------------

` Parse the string and translate the special characters

For ($WSPI_parser;1;Length($WSPI_MyString))

$WSPI_MyChar:=Substring($WSPI_MyString;$WSPI_parser;1)

Else 
$0:=$0+"%"
$WSPI_n:=Ascii($WSPI_MyChar)\16
If ($WSPI_n<10)
$0:=$0+String($WSPI_n)
Else 
$0:=$0+Char(Ascii("A")+$WSPI_n-10)
End if

$WSPI_n:=Ascii($WSPI_MyChar)%16

If ($WSPI_n<10)
$0:=$0+String($WSPI_n)
Else 
$0:=$0+Char(Ascii("A")+$WSPI_n-10)
End if

End if

End for 
`---------------- end -----------------

Anhang laden (2855 Bytes).

Hinweis: der Anhang wurde von 4D nicht getestet noch auf Funktion oder Viren überprüft.
Wir empfehlen als Anhang ausschließlich das .zip Format zu verwenden, das Sie vor dem Öffnen selbst mit einem aktuellen Viren-Scanner überprüfen sollten. Wir raten vom Öffnen von anderen Formaten ab.

Code ändern (nur für Autor - Kennwort geschützt)

Zurück

When the solution matters

International Sites

4D Produkte

Referenzen

Corporate

Support

Vertrieb

Menü

4D Code Library